cargs = ['-DG_LOG_DOMAIN="FuPluginSynapticsMST"']

install_data(['synapticsmst.quirk'],
  install_dir: join_paths(datadir, 'fwupd', 'quirks.d')
)

shared_module('fu_plugin_synapticsmst',
  fu_hash,
  sources : [
    'fu-plugin-synapticsmst.c',
    'fu-synapticsmst-common.c',
    'fu-synapticsmst-connection.c',
    'fu-synapticsmst-device.c',
  ],
  include_directories : [
    include_directories('../..'),
    include_directories('../../src'),
    include_directories('../../libfwupd'),
  ],
  install : true,
  install_dir: plugin_dir,
  c_args : [
    cargs,
  ],
  link_with : [
    libfwupdprivate,
  ],
  dependencies : [
    plugin_deps,
  ],
)

if get_option('tests')
  cargs += '-DFU_OFFLINE_DESTDIR="/tmp/fwupd-self-test"'
  cargs += '-DPLUGINBUILDDIR="' + meson.current_build_dir() + '"'
  cargs += '-DSOURCEDIR="' + meson.current_source_dir() + '"'
  e = executable(
    'synapticsmst-self-test',
    fu_hash,
    sources : [
      'fu-self-test.c',
      'fu-synapticsmst-common.c',
      'fu-synapticsmst-connection.c',
      'fu-synapticsmst-device.c',
    ],
    include_directories : [
      include_directories('../..'),
      include_directories('../../src'),
      include_directories('../../libfwupd'),
    ],
    dependencies : [
      plugin_deps,
      sqlite,
      valgrind,
    ],
    link_with : [
      libfwupdprivate,
    ],
    c_args : [
      cargs,
    ],
  )
  test('synapticsmst-self-test', e,
    env: ['FWUPD_LOCALSTATEDIR=/tmp/fwupd-self-test/var'])
endif