mirror of
https://git.proxmox.com/git/efi-boot-shim
synced 2025-08-03 17:27:55 +00:00
6450809720
We don't need to .data entries; the second one should be .data*. He's since fixed this in his tree, but I'd already pulled it and pushed to master. Signed-off-by: Peter Jones <pjones@redhat.com>
66 lines
1.1 KiB
Plaintext
66 lines
1.1 KiB
Plaintext
OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
|
|
OUTPUT_ARCH(arm)
|
|
ENTRY(_start)
|
|
SECTIONS
|
|
{
|
|
.text 0x0 : {
|
|
*(.text.head)
|
|
*(.text)
|
|
*(.text.*)
|
|
*(.gnu.linkonce.t.*)
|
|
*(.srodata)
|
|
*(.rodata*)
|
|
. = ALIGN(16);
|
|
_etext = .;
|
|
}
|
|
.dynamic : { *(.dynamic) }
|
|
.data :
|
|
{
|
|
*(.sdata)
|
|
*(.data)
|
|
*(.data1)
|
|
*(.data*)
|
|
*(.got.plt)
|
|
*(.got)
|
|
|
|
/* the EFI loader doesn't seem to like a .bss section, so we stick
|
|
it all into .data: */
|
|
. = ALIGN(16);
|
|
_bss = .;
|
|
*(.sbss)
|
|
*(.scommon)
|
|
*(.dynbss)
|
|
*(.bss)
|
|
*(COMMON)
|
|
. = ALIGN(16);
|
|
_bss_end = .;
|
|
}
|
|
|
|
. = ALIGN(4096);
|
|
.vendor_cert :
|
|
{
|
|
*(.vendor_cert)
|
|
}
|
|
. = ALIGN(4096);
|
|
|
|
.rel.dyn : { *(.rel.dyn) }
|
|
.rel.plt : { *(.rel.plt) }
|
|
.rel.got : { *(.rel.got) }
|
|
.rel.data : { *(.rel.data) *(.rel.data*) }
|
|
_edata = .;
|
|
_data_size = . - _etext;
|
|
|
|
. = ALIGN(4096);
|
|
.dynsym : { *(.dynsym) }
|
|
. = ALIGN(4096);
|
|
.dynstr : { *(.dynstr) }
|
|
. = ALIGN(4096);
|
|
/DISCARD/ :
|
|
{
|
|
*(.rel.reloc)
|
|
*(.eh_frame)
|
|
*(.note.GNU-stack)
|
|
}
|
|
.comment 0 : { *(.comment) }
|
|
}
|