mirror of
https://github.com/qemu/qemu.git
synced 2025-10-31 12:07:31 +00:00
aba378dee6
LLVM's linker, LLD, supports the keyword "INSERT AFTER", starting with version 11. However, when multiple sections are defined in the same "INSERT AFTER", they are added in a reversed order, compared to BFD's LD. This patch makes fork_fuzz.ld generic enough to work with both linkers. Each section now has its own "INSERT AFTER" keyword, so proper ordering is defined between the sections added. Signed-off-by: Daniele Buono <dbuono@linux.vnet.ibm.com> Message-Id: <20201105221905.1350-2-dbuono@linux.vnet.ibm.com> Reviewed-by: Alexander Bulekov <alxndr@bu.edu> Tested-by: Alexander Bulekov <alxndr@bu.edu> Signed-off-by: Thomas Huth <thuth@redhat.com>
57 lines
1.3 KiB
Plaintext
57 lines
1.3 KiB
Plaintext
/*
|
|
* We adjust linker script modification to place all of the stuff that needs to
|
|
* persist across fuzzing runs into a contiguous section of memory. Then, it is
|
|
* easy to re-map the counter-related memory as shared.
|
|
*/
|
|
|
|
SECTIONS
|
|
{
|
|
.data.fuzz_start : ALIGN(4K)
|
|
{
|
|
__FUZZ_COUNTERS_START = .;
|
|
__start___sancov_cntrs = .;
|
|
*(_*sancov_cntrs);
|
|
__stop___sancov_cntrs = .;
|
|
|
|
/* Lowest stack counter */
|
|
*(__sancov_lowest_stack);
|
|
}
|
|
}
|
|
INSERT AFTER .data;
|
|
|
|
SECTIONS
|
|
{
|
|
.data.fuzz_ordered :
|
|
{
|
|
/*
|
|
* Coverage counters. They're not necessary for fuzzing, but are useful
|
|
* for analyzing the fuzzing performance
|
|
*/
|
|
__start___llvm_prf_cnts = .;
|
|
*(*llvm_prf_cnts);
|
|
__stop___llvm_prf_cnts = .;
|
|
|
|
/* Internal Libfuzzer TracePC object which contains the ValueProfileMap */
|
|
FuzzerTracePC*(.bss*);
|
|
/*
|
|
* In case the above line fails, explicitly specify the (mangled) name of
|
|
* the object we care about
|
|
*/
|
|
*(.bss._ZN6fuzzer3TPCE);
|
|
}
|
|
}
|
|
INSERT AFTER .data.fuzz_start;
|
|
|
|
SECTIONS
|
|
{
|
|
.data.fuzz_end : ALIGN(4K)
|
|
{
|
|
__FUZZ_COUNTERS_END = .;
|
|
}
|
|
}
|
|
/*
|
|
* Don't overwrite the SECTIONS in the default linker script. Instead insert the
|
|
* above into the default script
|
|
*/
|
|
INSERT AFTER .data.fuzz_ordered;
|